;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;

; Author : ADI - Apps www.analog.com/MicroConverter

;

; Date : October 2003

;

; File : ADCtimer.asm

;

; Hardware : ADuC841

;

; Description : Performs ADC conversions at 120KSPS in Timer2 mode.

; Outputs ADC results on P0 & P2. Continuously

; flashes LED (independently of ADC routine) at

; approximately 5Hz.

; All rate calculations assume an 11.0592MHz Mclk.

;

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

$MOD841 ; Use 8052&ADuC841 predefined symbols

LED EQU P3.4 ; P3.4 drives red LED on eval board

CHAN EQU 0 ; convert this ADC input channel..

; ..chan values can be 0 thru 8

;\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_

; BEGINNING OF CODE

CSEG

ORG 0000h

JMP MAIN ; jump to main program

;\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_

; INTERRUPT VECTOR SPACE

ORG 0033H ; (ADC ISR)

MOV P0,ADCDATAL ; ADC result low byte to Port0

MOV P2,ADCDATAH ; high nibble and channel ID to Port2

RETI

;====================================================================

; MAIN PROGRAM

ORG 004Bh

MAIN:

; PRECONFIGURE...

MOV ADCCON1,#09Eh ; power up ADC & enable Timer2 mode

MOV ADCCON2,#CHAN ; select channel to convert

MOV RCAP2L,#0D2h ; sample period = 2 \* T2 reload prd

MOV RCAP2H,#0FFh ; = 2\*(10000h-FFD2h)\*90ns

MOV TL2,#0D2h ; = 2\*46\*90ns

MOV TH2,#0FFh ; = 8.28us

; LAUNCH Timer2 DRIVEN CONVERSIONS...

SETB EA ; enable interrupts

SETB EADC ; enable ADC interrupt

SETB TR2 ; run Timer2

; CONTINUE WITH OTHER CODE...

MOV A,#010 ; set delay length

AGAIN: CPL LED ; blink (complement) the LED

CALL DELAY ; delay 100ms

JMP AGAIN ; repeat

; the micro is free to continue with other tasks (flashing the LED in

; this case) while the ADC operation is being controlled by Timer2

; and the ADC interrupt service routine.

;\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_

DELAY: ; delay 10ms X A

MOV R5,A

DLY2: MOV R7,#090h

DLY1: MOV R6,#0FFh

DJNZ R6,$

DJNZ R7,DLY1

DJNZ R5,DLY2

RET

;\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_

END